 |
AutoHotkey Community
Wir helfen uns gegenseitig aus der Patsche
|
| Vorheriges Thema anzeigen :: Nächstes Thema anzeigen |
| Autor |
Nachricht |
swa
Anmeldedatum: 27.05.2007
Beiträge: 171
|
 Verfasst am: Do Jul 31, 2008 1:59 pm Titel: Gui problem |
 |
|
hey leute ich hab da ne problem ich hab folgene gui
| Code: | Gui, Add, DropDownList, x156 y100 w100 h21 , 1|1`,6
Gui, Add, Text, x156 y70 w100 h20 , Festmeter
Gui, Add, Text, x286 y70 w120 h20 , Holzart 1
Gui, Add, Text, x436 y70 w120 h20 , Holzart 2
Gui, Add, DropDownList, x286 y100 w120 h21 , Buche|Eiche
Gui, Add, Text, x26 y70 w100 h20 , Anzahl
Gui, Add, Edit, x26 y100 w100 h20 ,
Gui, Add, DropDownList, x436 y100 w120 h21 , Buche|Eiche
Gui, Add, Text, x216 y10 w110 h20 , Anzahl
Gui, Add, Edit, x216 y30 w110 h20 ,
Gui, Add, Button, x216 y130 w110 h20 , 1 Produkt mehr
; Generated using SmartGUI Creator 4.0
Gui, Show, x131 y91 h234 w578, New GUI Window
Return
GuiClose:
ExitApp |
nun würde ich sie gerne mit funktion füllen versage nur immer schrecklich
allso ich möchte es so machen das wenn ich eine zahl bei anzahl eingebe so oft die dropdownliste bzw die edit feld kommt
zudem wenn man auf denn button klickt sollte eine neue zeile mit diesen edit bzw ddl kommen
hoffe das einer mir die richtige erklärung bzw die richtige webseite schicken kann wo ich das lernen könnt ..
Danke im vorraus
und freudnliche grüße
swa |
|
| Nach oben |
|
 |
BoBo²
Gast
|
| Verfasst am: Do Jul 31, 2008 2:16 pm Titel: |
|
|
| Zitat: | | würde ich sie gerne mit funktion füllen versage nur immer schrecklich |
a) Ein erster Schritt wäre, auf den SmartGuiCreator zu verzichten. Durch die 'harte Schule' gegangen verinnerlicht sich einem die Funktionsweise der AHK-GUI Thematik um einiges schneller.
Ich kann dir allerdings auch schwer folgen. da mir das eigentliche Ziel nicht wirklich klar ist, also ...
a) Ein Kunde kauft Holz, und zwar ...
b) soundsoviel Festmeter Festmeter von Holzart 1
c) soundsoviel Festmeter Festmeter von Holzart 2
d) und dies in Buche oder Eiche
e) dabei ist die Anzahl (und da verließen sie ihn) ... |
|
| Nach oben |
|
|
swa
Anmeldedatum: 27.05.2007
Beiträge: 171
|
| Verfasst am: Do Jul 31, 2008 2:19 pm Titel: |
|
|
| wollte es so machen das es holzgemischt ist also gemisch Buche/eiche |
|
| Nach oben |
|
|
DerRaphael
Anmeldedatum: 09.01.2008
Beiträge: 1232
Wohnort: 127.0.0.1
|
| Verfasst am: Do Jul 31, 2008 2:46 pm Titel: |
|
|
verwende eine listview in deiner GUI zum anzeigen, was der Kunde denn kaufen möchte (art/menge/mengenart/einzelpreis/gesamtpreis) und eine weitere GUI, die nur dazu da ist jeweils einen Artikel zu erfassen.
das macht dein leben wesentlich einfacher. um einzelne elemente mit aktionen zu verbinden, gibt es die gLabel option (evtl mit AltSubmit). damit wird wenn jemand mit deinem GUI element arbeitet ein Gosub zum Label gemacht ... einzige vorraussetzung: es muss immer mit g (wie gosub) anfangen. Wie das Label heißt, ist egal. In deinem Skript, sollte das Label natürlich ohne das führende g Auftauchen, sonst meckert AHK.
ich hab mal aufgemalt, was ich meine:
Im Smalltalkforum gibt es von Thalon einen Thread mit einer herunterladbaren teildeutschen Hilfe. Dort ist auch der komplette Artikel zum Thema GUI übersetzt vorzufinden mit funktionierenden Beispielen 
dR
_________________
|
|
| Nach oben |
|
|
swa
Anmeldedatum: 27.05.2007
Beiträge: 171
|
| Verfasst am: Do Jul 31, 2008 2:51 pm Titel: |
|
|
meinst du die gui 1 so ?
| Code: | Gui, Add, ListView, x6 y10 w410 h320 , Mänge|Holzart1|Holzart2|Preis|Gesamtpreis
Gui, Add, Button, x16 y340 w110 h30 , Hinzufügen
Gui, Add, Button, x196 y340 w60 h30 , Okay
Gui, Add, Button, x256 y340 w60 h30 , verwerfen
; Generated using SmartGUI Creator 4.0
Gui, Show, x203 y143 h379 w419, New GUI Window
Return
GuiClose:
ExitApp
|
|
|
| Nach oben |
|
|
DerRaphael
Anmeldedatum: 09.01.2008
Beiträge: 1232
Wohnort: 127.0.0.1
|
| Verfasst am: Do Jul 31, 2008 2:57 pm Titel: |
|
|
auf den verwerfen knopf würde ich verzichten - aber ja, sowas meine ich
das verwerfen kannst du über ein kontext menü erledigen, dass sich in deine ListView einklinkt
Mänge|Holzart1|Holzart2|Preis|Gesamtpreis
es bleibt natürlich dir überlassen, jedoch würde ich da
"Laufende Nr,Art,Menge,Einheit,Preis pro Einheit,Gesamtbruttopreis,Gesamtnettopreis"
daraus machen
Und weiter unten in der Gui eine ReadOnly EditZeile mit einer Totalsumme
Enthaltene Mehrwertsteuer in Höhe von % sollte auch nicht fehlen.
edit mein fehler: der verwerfen knopf mach sinn - das ganze zu kippen, ich war irgendwie bei einzelposten, da macht es nämlich keinen sinn 
_________________
|
|
| Nach oben |
|
|
swa
Anmeldedatum: 27.05.2007
Beiträge: 171
|
| Verfasst am: Do Jul 31, 2008 3:03 pm Titel: |
|
|
okay danke deine idee war extrem gut
naja könntest du mir dann erklären wie ich ne gui öffne durch buttenklick bzw die daten aus der eingabe maske in die listview kommt ? |
|
| Nach oben |
|
|
DerRaphael
Anmeldedatum: 09.01.2008
Beiträge: 1232
Wohnort: 127.0.0.1
|
| Verfasst am: Do Jul 31, 2008 3:07 pm Titel: |
|
|
steht alles hier - musst es nur lesen beispiele sind enthalten
Gui - wie geht dem?
dR
_________________
|
|
| Nach oben |
|
|
swa
Anmeldedatum: 27.05.2007
Beiträge: 171
|
| Verfasst am: Do Jul 31, 2008 3:13 pm Titel: |
|
|
okay vielen dank ..
hab herausgefunden wie das mit gui 2 geht..
naja jetzt noch dran setzten wie ich das mache mit demm listview einfügen |
|
| Nach oben |
|
|
Obi-Wahn
Anmeldedatum: 19.04.2006
Beiträge: 729
Wohnort: Wien
|
| Verfasst am: Do Jul 31, 2008 3:22 pm Titel: |
|
|
Hi!
1.) Menge schreibt man mit "E"
2.) Würd ich die eingabefelder direkt unter der ListView machen
3.) Hat swa vmtl. am anfang sowas gemeint: | Code: | #Singleinstance, force
Start:
Gui, Destroy
CY := 100, CH := 20
BY := GY + CH + 10
; Ganz oben
Gui, Add, Text, x216 y10 w110 h20 , Anzahl
Gui, Add, Edit, x216 y30 w110 h20 Number gCalc vCount,
Gui, Add, Text, x26 y70 w100 h20 , Anzahl
Gui, Add, Edit, x26 y%CY% w100 h%CH% ,
Gui, Add, Text, x156 y70 w100 h20 , Festmeter
Gui, Add, DropDownList, x156 y%CY% w100 h%CH% , 1|1`,6
Gui, Add, Text, x286 y70 w120 h20 , Holzart 1
Gui, Add, DropDownList, x286 y%CY% w120 h%CH% , Buche|Eiche
Gui, Add, Text, x436 y70 w120 h20 , Holzart 2
Gui, Add, DropDownList, x436 y%CY% w120 h%CH% , Buche|Eiche
Gui, Add, Button, x216 y%BY% w110 h%CH% vButton, 1 Produkt mehr
Gui, Show, Center , Holzberechnung
Return
GuiClose:
ExitApp
Calc:
Gui, Submit, NoHide
If !Count
GoTo, Start
NCY := CY
Loop, %Count% {
NCY += CH + 10
Gui, Add, Edit, x26 y%NCY% w100 h%CH% ,
Gui, Add, DropDownList, x156 y%NCY% w100 h%CH% , 1|1`,6
Gui, Add, DropDownList, x286 y%NCY% w120 h%CH% , Buche|Eiche
Gui, Add, DropDownList, x436 y%NCY% w120 h%CH% , Buche|Eiche
NBY := NCY + 30
GuiControl, Move, Button, x216 y%NBY% w110 h%CH%
NGH := NBY + CH + 20
Gui, Show, Center h%NGH%, Holzberechnung
}
Return
|
_________________
Garten ist eine Kunstnatur
Das Leben ist nicht fair. Es ist nur fairer als der Tod, das ist alles.
Obi-Wahns Codeschnipsel @ securityvision.ch |
|
| Nach oben |
|
|
swa
Anmeldedatum: 27.05.2007
Beiträge: 171
|
| Verfasst am: Do Jul 31, 2008 3:23 pm Titel: |
|
|
jop genau so was meinte ich obi..
hatte da aber noch ne andere frage wie fülle ich die listview ?
also das mit lv_add
versteh ich schon aber wo soll das hin wenn es immer neu gemacht werden soll sobald die gui 2 geschlossen worden ist ? |
|
| Nach oben |
|
|
denick (n-l-i)
Gast
|
| Verfasst am: Do Jul 31, 2008 3:28 pm Titel: |
|
|
Moin,
wohl etwas spät, aber es geht schon auch anders:
| Code: | #NoEnv
Anzahl := 1
Gui, Margin, 20, 20
Gui, Add, Text, xm y10 w100 h20 , Anzahl
Gui, Add, Edit, xm y30 w100 h20 Right Number Limit1 vEDZ, 1
Gui, Add, Button, x+20 yp w100 h20 gAnzahlAnpassen, Anzahl anpassen
Gui, Add, Button, x+20 yp w100 h20 gPlusEins, 1 Produkt mehr
Gui, Add, Text, xm y70 w100 h20 , Anzahl
Gui, Add, Text, x+20 yp w100, Festmeter
Gui, Add, Text, x+20 yp w120, Holzart 1
Gui, Add, Text, x+20 yp w120, Holzart 2
Loop, 9 {
Gui, Add, Edit
, % "xm y+2 w100 h20 Right Number Limit3 vED" . A_Index
. (A_Index > 1 ? " Hidden" : "")
Gui, Add, DDL
, % "x+20 yp w100 r3 vDDL1" . A_Index . (A_Index > 1 ? " Hidden" : "")
, 1||1`,6
Gui, Add, DDL
, % "x+20 yp w120 r3 vDDL2" . A_Index . (A_Index > 1 ? " Hidden" : "")
, Buche||Eiche
Gui, Add, DDL
, % "x+20 yp w120 r3 vDDL3" . A_Index . (A_Index > 1 ? " Hidden" : "")
, Buche||Eiche
}
Gui, Show, Autosize, Holzverkauf
Return
; ------------------------------------------------------------------------------
GuiClose:
ExitApp
; ------------------------------------------------------------------------------
AnzahlAnpassen:
GuiControlGet, EDZ
If (EDZ = Anzahl)
Return
If (EDZ > Anzahl) {
Loop %EDZ% {
If (A_Index <= Anzahl)
Continue
GuiControl, , ED%A_Index%
GuiControl, Show, ED%A_Index%
GuiControl, Choose, DDL1%A_Index%, 1
GuiControl, Show, DDL1%A_Index%
GuiControl, Choose, DDL2%A_Index%, 1
GuiControl, Show, DDL2%A_Index%
GuiControl, Choose, DDL3%A_Index%, 1
GuiControl, Show, DDL3%A_index%
}
} Else {
If (EDZ < 1) {
EDZ := 1
GuiControl, , EDZ, %EDZ%
}
Loop %Anzahl% {
If (A_Index <= EDZ)
Continue
GuiControl, , ED%A_Index%
GuiControl, Hide, ED%A_Index%
GuiControl, Hide, DDL1%A_Index%
GuiControl, Hide, DDL2%A_Index%
GuiControl, Hide, DDL3%A_index%
}
}
Anzahl := EDZ
Gui, Show, Autosize
Return
; ------------------------------------------------------------------------------
PlusEins:
If !(Anzahl < 9)
Return
Anzahl++
GuiControl, , EDZ, %Anzahl%
GuiControl, Show, ED%Anzahl%
GuiControl, Show, DDL1%Anzahl%
GuiControl, Show, DDL2%Anzahl%
GuiCOntrol, Show, DDL3%Anzahl%
Gui, Show, Autosize
Return |
Schau mal!  |
|
| Nach oben |
|
|
swa
Anmeldedatum: 27.05.2007
Beiträge: 171
|
| Verfasst am: Do Jul 31, 2008 3:29 pm Titel: |
|
|
wow das ist cool ..
find eich sogar besser als die listview..
übersichtlicher..
naja schauen wie man das speichern kann .. |
|
| Nach oben |
|
|
BoBo²
Gast
|
| Verfasst am: Do Jul 31, 2008 3:30 pm Titel: |
|
|
Tu dir selbst eine Gefallen, und setze bei der Anzahl ein Limit. Eine > 10000 Eingabefelderzeilen lange GUI ist irgendwie, na ja, ähh, ...  |
|
| Nach oben |
|
|
swa
Anmeldedatum: 27.05.2007
Beiträge: 171
|
| Verfasst am: Do Jul 31, 2008 3:31 pm Titel: |
|
|
| jo das ist ne super idee .... |
|
| Nach oben |
|
|
|
|
Du kannst Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum antworten.
|
Powered by phpBB © 2001, 2005 phpBB Group
Deutsche Übersetzung von phpBB.de |
FAQ
Suchen
Mitgliederliste
Registrieren
Profil
Einloggen, um private Nachrichten zu lesen
Login
