 |
AutoHotkey Community
Wir helfen uns gegenseitig aus der Patsche
|
| Vorheriges Thema anzeigen :: Nächstes Thema anzeigen |
| Autor |
Nachricht |
fredchf
Anmeldedatum: 18.09.2006
Beiträge: 1145
Wohnort: Deutschland
|
 Verfasst am: So Dez 23, 2007 2:47 am Titel: Radio-LiveStream für den Systray NDR 2 und Co. |
 |
|
Hallo,
das ist ein kleines Programm für Live-Radio-Streams mit dem Media Player!
Der Mediaplayer startet im Hintergrund und lässt sich über das Trayicon bedienen.
(Titelinfos für einige Sender,SWR3,NDR2,NDR1,WDR4,Moskau Radio - DeepMix)
Unterstützt werden nat. auch "normale" Playlists! 
Zip-Version letzte Änderung, Datum: 22.02.2012
Exe-Version(Installer) letzte Änderung, Datum: 22.02.2012
EDIT:
Änderungen Datum:
* 23:17 Dienstag, 21. Februar 2012 v1.1.3.4
* Titelinformationen ein-ausblenden
* Titelinformationen Radio SAW
* 15:30 Mittwoch, 15. Februar 2012 v1.1.3.2
* mögliche Fehler bei Markierung eines nicht vorhandenen Menüeintrags
* Anpassung beim Import des Texten aus IE
* 18:40 Dienstag, 14. Februar 2012 v1.1.3.1
* laden der Titelinformationen nun über COM(Internet Explorer)
* 10:18 Sonntag, 12. Februar 2012 2012 v1.1.3.0
* Anpassungen an Win 7(%A_AppData% als ini-Ordner)
* Gruppierung der Playlists in Ordnerstruktur
*
* 19:39 Dienstag, 7. Februar 2012 v1.1.2.9
* größere Anpassungen an AHK_L
* VLC-Wiedergabe entfernt
* Icons für Menüpunkte
| Code: | /*
; ------------------------------------------------------------------------------
Credis:
- jethrow for COM Object: WMPlayer.OCX
http://www.autohotkey.com/forum/post-419623.html&sid=c0986766db3d83443a3867f84c4c18ee#419623
; ------------------------------------------------------------------------------
Playlists und Icons kannst du selbst erweitern/löschen,Icon muss den gleichen Namen tragen wie die Playlist(pls,m3u,asf).
In %A_ScriptDir%\PL\ werden sie gespeichert
*/
SetBatchLines, -1
#Persistent
SplitPath, A_ScriptFullPath, OutFileName, OutDir, OutExtension, Filename, OutDrive
if A_IsCompiled
FileGetVersion, vv, %A_ScriptName%
Else
IniRead, vv, %A_ScriptName%.ini, VERSION, FILE_VER, 0
FileGetTime, script_time, %A_ScriptName%
FormatTime, script_time2, %script_time%,
; ------------------------------------------------------------------------------
version = V%vv% vom %script_time2%
pfad = %A_SCRIPTDIR%\PL ;rootverzeichnis für Playlists
ext = m3u,pls,asf ;zu beachtene erweiterungen
ini = Settings_%Filename%.ini
gui_el = 400
; ------------------------------------------------------------------------------
if A_ScriptDir = %A_ProgramFiles%\LiveRadio
{
IfNotExist, %A_AppData%\Live-Radio
{
FileCreateDir, %A_AppData%\Live-Radio
if ErrorLevel
{
MsgBox, Der Einstellungsordner konnte nicht angelegt werden. Abbruch!
ExitApp
}
}
ini = %A_AppData%\Live-Radio\%ini%
}
; ------------------------------------------------------------------------------
Gosub, iniread
IfNotExist, %pfad%
{
MsgBox, 16, Fehler!, Das Playlist-Verzeichnis(PL) konnte nicht gefunden werden!`nAbbruch!
ExitApp
}
Loop, %pfad%\*.*, 2,
{
ordner = %A_LoopFileName%
Loop, %pfad%\%ordner%\*.*,
{
if A_LoopFileExt not in %ext%
Continue
SplitPath, A_LOOPFILEFULLPATH , OutFileName, OutDir, OutExtension, OutNameNoExt, OutDrive
menu, %ordner%, add, %OutNameNoExt%, menuhandler
IfExist, %OutDir%\%OutNameNoExt%.ico
Menu, %ordner%, icon, %OutNameNoExt%, %OutDir%\%OutNameNoExt%.ico
IfNotInString, ch, |%ordner%
{
ch .= "|" ordner
menu, m3u, add, %ordner%, :%ordner%
Menu, m3u, icon, %ordner%, %A_Windir%\system32\shell32.dll, 4
}
}
}
If hotke != kein
Hotkey, %hotke%, hotke, ON
If hotkek != kein
Hotkey, %hotkek%, hotkek, ON
Menu, tray, NoStandard
Menu, Tray, tip, - %m3u3% - %A_ScriptName%
Menu, Tray, Add, Playlist, :m3u
Menu, Tray, icon, Playlist, %A_Windir%\system32\shell32.dll, 4
Menu, Tray, Add
Menu, Tray, Add, Titelinformationen (falls vorhanden), toogle_titel
Menu, Tray, Add, Player neu starten (%hotke%), hotke
Menu, Tray, Add, Info, about
Menu, Tray, icon, Info, %A_Windir%\system32\shell32.dll, 222
Menu, Tray, Add, Beenden - %playerv% (%hotkek%), ende
Menu, Tray, icon, Titelinformationen (falls vorhanden), %A_Windir%\system32\shell32.dll, 2
Menu, Tray, icon, Beenden - %playerv% (%hotkek%), %A_Windir%\system32\shell32.dll, 132
if titelinfo
Menu, Tray, Check, Titelinformationen (falls vorhanden)
SplitPath, m3u , OutFileName, OutDir, OutExtension, OutNameNoExt, OutDrive
StringReplace, mitem, OutDir, % A_ScriptDir "\PL\" , , All
if (mitem)
try ; vermeidet Fehler bei Markierung eines Eintrages
{
Menu, %mitem%, Check, %m3u3%
}
Gui, +ToolWindow
Gui, +AlwaysOnTop
Gui, Color, F4F3FF
Gui, font, s14, Verdana
Gui, Add, Progress, vproz -Smooth 0x8 w%gui_el% h18
Gui, Add, Text, +Center CNavy vload w%gui_el%, %playerv% wird geladen...
if FileExist(OutDir "\" OutNameNoExt ".ico")
Gui, Add, Picture, % "x" gui_el // 2 - 10 " h-1 +Center", % OutDir "\" OutNameNoExt ".ico"
Gui, Show, , Bitte warten!.....%m3u3%.....
SetTimer, Push, 45
Gosub, trayt
SetTimer, trayt ,20000
if !titelinfo
SetTimer, trayt ,Off
wmp := ComObjCreate("WMPlayer.OCX")
ComObjConnect(wmp, "wmp_") ; show player status in TrayTip
wmp.url := m3u ; play file
Loop
{
GuiControl, , load, % wmp.status
SLEEP, 200
if (A_Index > 100 or InStr(wmp.status, "Wiedergabe von") or InStr(wmp.status, "Wiedergabe:"))
BREAK
Continue
}
SetTimer, Push, Off
Gui, Show, Hide, Bitte warten!
TrayTip, %m3u3%, Weitere Optionen mit Rechtsklick...`n%trayt%, 20
ONEXIT, exit
Return
; ######################### mit ausgewählter playlist neustart
menuhandler:
IfExist, %pfad%\%A_ThisMenu%\%A_ThisMenuItem%.m3u
{
m3u = %pfad%\%A_ThisMenu%\%A_ThisMenuItem%.m3u
m3u2 = %A_ThisMenuItem%.m3u
}
IfExist, %pfad%\%A_ThisMenu%\%A_ThisMenuItem%.pls
{
m3u = %pfad%\%A_ThisMenu%\%A_ThisMenuItem%.pls
m3u2 = %A_ThisMenuItem%.pls
}
IfExist, %pfad%\%A_ThisMenu%\%A_ThisMenuItem%.asf
{
m3u = %pfad%\%A_ThisMenu%\%A_ThisMenuItem%.asf
m3u2 = %A_ThisMenuItem%.asf
}
mitem = %ordner%
hotke:
Gosub, iniwrite
Reload
; ######################### fortschritsbalken bewegen
Push:
GuiControl, , proz, 1
Return
; #########################
iniwrite:
IniWrite, %vorlauf%, %ini%, player, vorlauf
IniWrite, %m3u%, %ini%, playlist, m3u
IniWrite, %m3u2%, %ini%, playlist, m3u2
IniWrite, %hotke%, %ini%, player, HK
IniWrite, %hotkek%, %ini%, player, HKK
IniWrite, %mitem%, %ini%, player, mitem
IniWrite, %titelinfo%, %ini%, player, titelinfo
if ErrorLevel
MsgBox, Die Einstellungen konnten leider nicht korrekt geschrieben werden.`n%A_ScriptDir%\%ini%`nEventuell reichen die Schreibrechte nicht aus.(Installation in einen anderen Ordner könnte helfen)
Return
; #########################
iniread:
IniRead, vorlauf, %ini%, player, vorlauf, 3
IniRead, m3u, %ini%, playlist, m3u, %A_ScriptDir%\PL\N\NDR 2.m3u
IniRead, m3u2, %ini%, playlist, m3u2, NDR 2.m3u
IniRead, hotke, %ini%, player, HK, ^#r
IniRead, hotkek, %ini%, player, HKK, ^#k
IniRead, mitem, %ini%, player, mitem, %A_SPACE%
IniRead, titelinfo, %ini%, player, titelinfo, 1
StringTrimRight, m3u3, m3u2, 4
Gosub, icon
Return
; ######################## trayicon setzen
icon:
SplitPath, m3u, OutFileName, OutDir, OutExtension, OutNameNoExt, OutDrive
IfExist, %OutDir%\%OutNameNoExt%.ico
Menu, tray, icon, %OutDir%\%OutNameNoExt%.ico
Else
Menu, tray, icon, %A_ScriptDir%\PL\LiveRadio Standart.ico
Return
; ######################### beenden
hotkek:
GuiClose:
ende:
Gosub, iniwrite
wmp.close
wmp := "" ; release/disconnect object
ExitApp
; ######################### infotext
about:
txt =
(
Das ist ein kleines Programm für Live-Radio-Streams mit dem Media Player!
Der MediaPlayer startet im Hntergrund.
Playlists und Icons kannst du selbst erweitern/löschen,
Icon muss den gleichen Namen tragen wie die Playlist(pls,m3u,asf).
In
%A_ScriptDir%\PL\
werden sie gespeichert.
gewählter Player:`t%playerv%
Version:`t%version%
)
txt2 =
(
aktueller Sender:`t%m3u2%
)
Guisiz = 900
Gui 2: font, s9, Verdana
Gui 2: Add, Picture, Icon222 , Shell32.dll
Gui 2: add, text, x+15, %txt%
Gui 2: add, text, h40, %txt2%
SplitPath, m3u , OutFileName, OutDir, OutExtension, OutNameNoExt, OutDrive
if FileExist(OutDir "\" OutNameNoExt ".ico")
Gui 2: Add, Picture, x+15 yp-15 w40 h-1, % OutDir "\" OutNameNoExt ".ico"
Gui 2: Add, edit, x55 y+1 w600 +ReadOnly, % "aktueller Titel: " trayt
Gui 2: add, Button, +Default x55 yp+50 w35, OK
Gui 2: show,
Return
; -------------------------------------------------------------------------
toogle_titel:
titelinfo := !titelinfo
if titelinfo
{
Menu, Tray, Check, Titelinformationen (falls vorhanden)
SetTimer, trayt ,On
}
Else
{
Menu, Tray, UnCheck, Titelinformationen (falls vorhanden)
SetTimer, trayt ,Off
}
Return
; -------------------------------------------------------------------------
2ButtonOK:
; MsgBox
Gui 2: Destroy
Return
; -------------------------------------------------------------------------
trayt:
trayt_old := trayt
trayt := wmp.status
If m3u2 = WDR 4.m3u
trayt := titeltip4() "`n" wmp.status
If m3u2 = NDR 1 Niedersachsen.m3u
trayt := titeltip3() "`n" wmp.status
If m3u2 = SWR3.m3u
trayt := titeltip() "`n" wmp.status
if m3u2 = Moskau Radio - DeepMix.m3u
trayt := wmp.status
if m3u2 = Radio SAW.m3u
trayt := saw() "`n" wmp.status
if m3u2 = fresh80s.m3u
trayt := fresh80s() "`n" wmp.status
if m3u2 = ffn.m3u
trayt := ffn() "`n" wmp.status
if m3u2 = NDR 2.m3u
trayt := titeltip2() "`n" wmp.status
Menu, Tray, tip, % "- " m3u3 " - " A_ScriptName "`naktueller Titel:`n" trayt
if (trayt_old != trayt)
TrayTip, %m3u3%, % "Weitere Optionen mit Rechtsklick...`n" trayt, 20
Return
; -------------------------------------------------------------------------
; Funktion zum ermitteln des aktuellen Titels SWR3
titeltip()
{
; einstellungen
link = http://www.swr3.de/index.php
sestr := "Jetzt läuft:"
str := f_text_from_web(link)
Loop, Parse, str , `n, `r
{
if RegExMatch(A_LoopField, sestr)
dd = %A_Index%
if (dd and A_Index = dd + 1)
Return RegExReplace(A_LoopField, " Webradio Suche" , "")
}
Return "nix gefunden"
}
; -------------------------------------------------------------------------
; Funktion zum ermitteln des aktuellen Titels NDR2
; <th id="row_1" scope="row">Jetzt läuft:</th>
; <td headers="row_1" id="webradio_song_now">Lena - Touch A New Day</td>
titeltip2()
{
link = http://www.ndr2.de ;/pages_idx_lib/0,,SPM6962,00.html
sestr := "Jetzt läuft:"
str := f_text_from_web(link)
Loop, Parse, str , `n, `r
{
; TOOLTIP, % A_LoopField
if RegExMatch(A_LoopField, sestr)
dd = %A_Index%
if (dd and A_Index = dd + 1)
Return A_LoopField
}
Return "nix gefunden"
}
; -------------------------------------------------------------------------
; Funktion zum ermitteln des aktuellen Titels NDR1
titeltip3()
{
; einstellungen
link = http://www.ndr1niedersachsen.de ;/pages_idx_lib/0,,SPM6962,00.html
sestr := "Jetzt läuft:"
str := f_text_from_web(link)
Loop, Parse, str , `n, `r
{
if RegExMatch(A_LoopField, sestr)
dd = %A_Index%
if (dd and A_Index = dd + 1)
Return A_LoopField
}
Return "nix gefunden"
}
; ------------------------------------------------------------------------------
; Funktion zum ermitteln des aktuellen Titels WDR4
titeltip4()
{
; einstellungen
link = http://www.wdr.de/radio/wdr4/playlist ;/pages_idx_lib/0,,SPM6962,00.html
sestr := "Von:Sendung:Bis:"
str := f_text_from_web(link)
Loop, Parse, str , `n, `r
{
if RegExMatch(A_LoopField, sestr)
dd = %A_Index%
if (dd and A_Index = dd + 2)
Return RegExReplace(A_LoopField, ".*Uhr", "")
}
Return "nix gefunden"
}
; ------------------------------------------------------------------------------
ffn()
{
link = http://www.ffn.de/
sestr := "ON AIR:\d+:\d+ (.*)WebradioPlaylist"
str := f_text_from_web(link)
Loop, Parse, str , `n, `r
{
; TOOLTIP, % A_LoopField
if RegExMatch(A_LoopField, sestr, un)
Return RegExReplace(un1, "(.+)\|(.+)", "$T1 : $T2")
}
Return "nix gefunden"
}
; ------------------------------------------------------------------------------
fresh80s()
{
link = http://www.fresh80s.de/onair/xml_shoutcast.php
str := f_text_from_web(link)
Loop, Parse, str , `n, `r
{
if (A_INDEX = 3)
bb := A_LoopField
if (A_INDEX = 4)
{
tt := A_LoopField
Return bb " : " tt
}
}
Return "nix gefunden"
}
; -------------------------------------------------------------------------
saw()
{
link = http://www.radiosaw.de/start.php?playlist
str := f_text_from_web(link)
Loop, Parse, str , `n, `r
{
if (A_INDEX = 39)
Return A_LoopField
}
Return "nix gefunden"
}
; -------------------------------------------------------------------------
^#p:: ; PL-Menü aufrufen
Menu, m3u, Show
Return
; -------------------------------------------------------------------------
^#UP::
next := (position = 1 ? anzahl_pl : (position - 1))
Gosub, nex
Return
; -------------------------------------------------------------------------
^#DOWN::
next := (position = anzahl_pl ? 1 : (position + 1))
Gosub, nex
Return
; -------------------------------------------------------------------------
nex: ; nächste PL
Loop, %A_ScriptDir%\PL\*.*
{
SplitPath, A_LoopFileFullPath, OutFileName, OutDir, OutExtension, OutNameNoExt, OutDrive
If OutExtension in m3u,pls,asf
{
anzahl_pl2++
If anzahl_pl2 = %next%
{
m3u = %A_LoopFileFullPath%
m3u2 = %A_LoopFileName%
Gosub, hotke
}
}
}
Return
; ------------------------------------------------------------------------------
f_text_from_web(URL)
{
pwb := ComObjCreate("InternetExplorer.Application")
; pwb.visible := true
pwb.Silent := True ; Scriptfehler ausblenden
pwb.Navigate(url)
While (pwb.readyState <> 4 || pwb.document.readystate <> "complete" || pwb.busy) && A_Index < 3000
Sleep, 50
str := pwb.Document.body.innertext, pwb.quit
Return str
}
; ------------------------------------------------------------------------------
exit:
wmp.close
wmp := "" ; release/disconnect object
ExitApp
; ------------------------------------------------------------------------------
/*
* 23:17 Dienstag, 21. Februar 2012 v1.1.3.4
* Titelinformationen ein-ausblenden
* Titelinformationen Radio SAW
*
* 00:08 Dienstag, 21. Februar 2012 v1.1.3.3
* Titelinformationen für fresh80s und ffn hinzugefügt
* 15:30 Mittwoch, 15. Februar 2012 v1.1.3.2
* mögliche Fehler bei Markierung eines nicht vorhandenen Menüeintrags
* Anpassung beim Import des Texten aus IE
* 18:40 Dienstag, 14. Februar 2012 v1.1.3.1
* laden der Titelinformationen nun über COM(Internet Explorer)
* 10:18 Sonntag, 12. Februar 2012 v1.1.3.0
* Anpassungen an Win 7(%A_AppData% als ini-Ordner)
* Gruppierung der Playlists in Ordnerstruktur
*
* 19:39 Dienstag, 7. Februar 2012 v1.1.2.9
* größere Anpassungen an AHK_L
* VLC-Wiedergabe entfernt
* Icons für Menüpunkte
* 01:22 Montag, 7. März 2011 v1.1.2.9
* Titelanzeige für NDR2 angepasst
* SAW hinzugefügt
*
* 01:06 Samstag, 22. Januar 2011 v1.1.2.8
* IDLast für M$ Mediaplayer
|
_________________
Mit freundlichen Grüßen
fredchf
Zuletzt bearbeitet von fredchf am Mi Feb 22, 2012 2:24 am, insgesamt 38-mal bearbeitet |
|
| Nach oben |
|
 |
Chucky
Anmeldedatum: 07.01.2006
Beiträge: 935
Wohnort: Land der tausend Berge
|
| Verfasst am: Di Dez 25, 2007 12:00 am Titel: |
|
|
Nette Idee  , geht auch gut mit WinAmp.
Gibt's eigentlich im Web eine Liste mit Stream-Adressen regionaler Webradios (wenn ja, wo) ? Also nicht (nur) die "besten Hits der 80er 90er"-Sender o. ä., sondern (auch) NDR, WDR, BR, MDR, HR usw. ? |
|
| Nach oben |
|
|
fredchf
Anmeldedatum: 18.09.2006
Beiträge: 1145
Wohnort: Deutschland
|
| Verfasst am: Di Dez 25, 2007 12:32 am Titel: |
|
|
Hallo Chucky,
meinst Du vielleicht sowas hier?
http://web.ard.de/radio/radionet/
Ich hatte eigentlich eine andere Seite benutzt,die ich jetzt aber nicht finden kann!  
_________________
Mit freundlichen Grüßen
fredchf
|
|
| Nach oben |
|
|
fredchf
Anmeldedatum: 18.09.2006
Beiträge: 1145
Wohnort: Deutschland
|
| Verfasst am: Di Dez 25, 2007 12:36 am Titel: |
|
|
jetzt habe ich es 
| Zitat: | | Nette Idee Cool, geht auch gut mit WinAmp. |
Ja,nur ist Winamp bei mir mit einigen PlugIns mittlerweile recht langsam startend!  Den MediaPlayer hat eigentlich jeder,der startet zügig und wird sonst bei mir nicht genutzt.(bevorzuge VLC und Winamp)
_________________
Mit freundlichen Grüßen
fredchf
|
|
| Nach oben |
|
|
Chucky
Anmeldedatum: 07.01.2006
Beiträge: 935
Wohnort: Land der tausend Berge
|
| Verfasst am: Di Dez 25, 2007 11:56 pm Titel: |
|
|
Genau sowas meinte ich, Dein erster Link war auch schon gut. Danke für Deine Recherche ! | Zitat: | | Ja,nur ist Winamp bei mir mit einigen PlugIns mittlerweile recht langsam startend! |
Ich benutze standhaft seit Jahren den Winamp 2.91  , der ist schnell. Für exotischere Formate nehme ich ebenfalls den VLC-Player; den MediaPlayer nur, wenn's wirklich nicht anders geht.
__________________________________________
Created with BBCodeWriter 7.0 - the one and only  |
|
| Nach oben |
|
|
Catman
Anmeldedatum: 02.02.2007
Beiträge: 38
|
| Verfasst am: So Jan 27, 2008 8:40 pm Titel: |
|
|
He, das ist mal nee cooles Teil. Ich höre oft beim Surfen Radio. Und es nervt sich immer durch die ganzen Links zu klick0rn bis man am Stream ist.
Eine Frage hätte ich dennoch. Wäre es denn möglich mehrere Streams in einem Script unter zu bringen, so das man über das Trayicon z.B. über nen Rechtsklick eine Auswahl seiner Lieblingsender hat, und dann zur Not wechseln kann?
Ich bin ehrlich, ich hab null Plan davon, aber AHK ist der Hammer, es macht das Leben mit dem Pc angenehmer!
|
|
| Nach oben |
|
|
fredchf
Anmeldedatum: 18.09.2006
Beiträge: 1145
Wohnort: Deutschland
|
| Verfasst am: So Jan 27, 2008 9:41 pm Titel: |
|
|
hi catman,
klar ist das möglich!
hatte ich mir auch eigentlich vorgenommen,aber weil ich eigentlich nur ndr2 höre und die resonanz bescheiden war,habe ich keine weitere arbeit investiert. 
wenn es dir freude machen sollte,kann ich das leicht beenden!?
_________________
Mit freundlichen Grüßen
fredchf
|
|
| Nach oben |
|
|
Catman
Anmeldedatum: 02.02.2007
Beiträge: 38
|
| Verfasst am: Mo Jan 28, 2008 12:24 am Titel: |
|
|
Das wär fein, was soll ich für Zuarbeit leisten?
|
|
| Nach oben |
|
|
fredchf
Anmeldedatum: 18.09.2006
Beiträge: 1145
Wohnort: Deutschland
|
| Verfasst am: Mo Jan 28, 2008 12:41 am Titel: |
|
|
hallo,
schon erledigt,siehe anfangspost!
du kannst es ja nach deinen wünschen umbauen oder verfeinern.
_________________
Mit freundlichen Grüßen
fredchf
|
|
| Nach oben |
|
|
Catman
Anmeldedatum: 02.02.2007
Beiträge: 38
|
| Verfasst am: Mo Jan 28, 2008 12:04 pm Titel: |
|
|
Da sag ich nur: "Ganz grosses Kino!"
Ich bin einfach nur begeistert, danke für die schnelle Antwort, und natürlich auch für dein Engagement!
|
|
| Nach oben |
|
|
fredchf
Anmeldedatum: 18.09.2006
Beiträge: 1145
Wohnort: Deutschland
|
| Verfasst am: Mi Jan 30, 2008 7:17 am Titel: |
|
|
hallo!
ich habe das script jetzt mal so angepasst,das sich jeder leicht seine eigenen playlist und icons hizufügen kann! die playlists und dazugehörigen icons werden jetzt in einem unterverzeichnis gespeichert,erkannt und dann automatisch ins das traymenü aufgenommen
nebenbei habe ich die zahl,siehe oben,der integrierten playlists(radio-streams)deutlich erhöht.(anregung von catman)
_________________
Mit freundlichen Grüßen
fredchf
|
|
| Nach oben |
|
|
Lirave
Anmeldedatum: 02.10.2007
Beiträge: 231
|
| Verfasst am: Mi Jan 30, 2008 12:26 pm Titel: |
|
|
ich habe dazu mal ne frage
ich habe die exe runtergeladen und installiert und dann gestartet
dann habe ich den vlc player ausgewählt und dann habe ich jump ausprobiert
klappt bis jetzt alles perfekt
aber es klappt nicth bei Hit radio sachsen
( die anderen habe ich jetzt noch nciht probiert)
und dann hätte ich noch ne frage, ist es möglich mit einem Hotkey eine Aufnahme zu starten?
(natürlich nur wenn es legal ist, kenne mich da nciht 100% aus)
ist ein super Programm respekt
_________________
Gruß Lirave |
|
| Nach oben |
|
|
BoBo¨
Gast
|
| Verfasst am: Mi Jan 30, 2008 2:27 pm Titel: |
|
|
*verdammt mir fehlt das *würg*-icon*
Wenns für mich nen Grund gibt ab Landesgrenze das Radio abzuschalten dann den.
Diese,
"Ich-Duz-meine-Zuhörer-weil-ich-dann-als-berufsjugendlicher-einfach-viel-cooler-rüberkomme-wenn-ich-action-news-ankündige-
-die-nichts-anderes-sind-als-britney-spears-news-und-zwischen-der-grusel-mucke-der-80er-und-90er-die-brauchbarste-information-
-die-warnung-vor-ner-radarfalle-in-weixdorf-ist",
gehn mir aufn keks und werden nur noch getoppt von "Nu nu, Mutti - alles gute zu deinem Ehrentag *wobei im Hintergrund bereits Rex Gildo angespielt wird*"
Degustibus non est disputandum |
|
| Nach oben |
|
|
fredchf
Anmeldedatum: 18.09.2006
Beiträge: 1145
Wohnort: Deutschland
|
| Verfasst am: Mi Jan 30, 2008 2:59 pm Titel: |
|
|
hi bobo!
| Zitat: | | *verdammt mir fehlt das *würg*-icon* |
ich kenne diesen sender zwar nicht persönlich,aber sender ,auf die diese beschreibung passen könnte, gibt es sicher in jeder region!
_________________
Mit freundlichen Grüßen
fredchf
|
|
| Nach oben |
|
|
garry
Anmeldedatum: 25.10.2005
Beiträge: 906
Wohnort: switzerland
|
| Verfasst am: Mi Jan 30, 2008 8:28 pm Titel: |
|
|
danke für's program fredchf
Lirave
| Zitat: | | und dann hätte ich noch ne frage, ist es möglich mit einem Hotkey eine Aufnahme zu starten? |
hier ein Beispiel mit streamripper
hatte den letzten streamripper downloaded, bekam aber mehrere Fehlermeldungen, intl.dll fehlt ( und weitere Fehler )
könnt ihr paar Beispiele zeigen ?
http://streamripper.sourceforge.net/
http://sourceforge.net/project/showfiles.php?group_id=6172&package_id=135477&release_id=548485
http://downloads.sourceforge.net/streamripper/streamripper-win32-1.63-beta-1.zip?modtime=1192968639&big_mirror=0
im script unten ein Downloadlink ältere Version ,wird nur benötigt :
streamripper.exe und tre.dll
das Beispiel hier funktioniert mit dem älteren streamripper
PLAY1=plays radio hawaii
RECORD1=record radio hawaii
DOWNLOAD2=download ein scetch von HR3 (mp3-datei)
RECORDED= öffnet folder c:\_recording
wie bekomme ich hin das die MP3 Datei in ordner C:\_recording\HR3\Hellseher.mp3 heisst ?
(sonst auch urldownloadtofile Befehl benützen)
im Moment:
C:\_RECORDING\HR3\Streamripper_rips\sr_program_2008_01_30_20_21_55.mp3
| Code: | MODIFIED=20080130
/*
streamripper example
records radio or download mp3 to c:\_recording
*/
STR=%A_scriptdir%\STREAMRIPPER
ifnotexist,%STR%
FileCreateDir,%STR%
STREAMRIPPER =%A_scriptdir%\streamripper\streamripper.exe
ifnotexist,%streamripper%
goto,dnl
C1=Hawaii
C3=http://70.84.73.66:8000
Gui,1:Add,Button,x10 y10 h25 w100 gPLAY1 ,PLAY1
Gui,1:Add,Button,x10 y40 h25 w100 gRECORD1 ,RECORD1
Gui,1:Add,Button,x120 y10 h25 w100 gDOWNLOAD2 ,DOWNLOAD2
Gui,1:Add,Button,x230 y10 h25 w100 gRECORDED ,RECORDED
Gui,1:Show, x100 y50 w370 h70,RADIO
return
;----------------------------------------------------
PLAY1:
Gui,1:submit,nohide
adre=%C1%.pls
ifnotexist,%adre%
Fileappend,[playlist]`nNumberOfEntries=1`nFile1=%C3%`n,%adre%
run,%adre%
return
;----------------------------
RECORD1:
Gui,1:submit,nohide
ifexist,%streamripper%
run,%COMSPEC% /K "%streamripper%" %C3% --xs_padding=7000:9000 -t -d c:\_recording
return
;-----------------------------
DOWNLOAD2:
runwait,%COMSPEC% /c "%streamripper%" http://www.hr-online.de/website/static/podcasting/hr3_lachenmitklaus/Hellseher.mp3 -a -c -T -A -d c:\_recording\HR3,,hide
Loop,C:\_recording\HR3\Streamripper_rips\*.cue
{
Filedelete,%A_LoopFileFullPath%
}
run,c:\_recording\HR3\Streamripper_rips
return
;-----------------------------
RECORDED:
run,c:\_recording
return
;----------------------------
guiclose:
exitapp
;----------------------------
dnl:
{
text31=
(
Download
-streamripper.exe with tre.dll and put in subfolder Streamripper
from
http://streamripper.sourceforge.net/
Want you download these programs ?
)
msgbox, 262180, Start URL,%text31%
ifmsgbox,NO
{
exitapp
return
}
else
{
;run,http://streamripper.sourceforge.net/
;run,http://sourceforge.net/project/showfiles.php?group_id=6172&package_id=135477&release_id=548485
;run,http://downloads.sourceforge.net/streamripper/streamripper-win32-1.63-beta-1.zip?modtime=1192968639&big_mirror=0
run,http://www.autohotkey.net/~garry/WGETSTREAMMP3DIRECTCUT.zip
exitapp
return
}
}
return
|
|
|
| Nach oben |
|
|
|
|
Du kannst keine Beiträge in dieses Forum schreiben.
Du kannst auf Beiträge in diesem Forum nicht antworten.
|
Powered by phpBB © 2001, 2005 phpBB Group
Deutsche Übersetzung von phpBB.de |
FAQ
Suchen
Mitgliederliste
Registrieren
Profil
Einloggen, um private Nachrichten zu lesen
Login
