FileCopyDir

Kopiert einen Ordner mit allen Unterordnern und Dateien (vergleichbar mit xcopy).

FileCopyDir, Source, Dest [, Flag]

Parameter

Source Der Name des Quellordners (ohne Backslash (\) am Ende). Als Standardordner wird %A_WorkingDir% angenommen, sollte kein absoluter Pfad angegeben sein.
Zum Beispiel: C:\Mein Ordner
Dest Der Name des Zielordners (ohne Backslash (\) am Ende). Als Standardordner wird %A_WorkingDir% angenommen, sollte kein absoluter Pfad angegeben sein.
Zum Beispiel: C:\Backup
Flag

(optional) dieser Parameter gibt an, ob bereits vorhandene Dateien überschrieben werden sollen, oder nicht.

0 (Standard): Dateien nicht überschreiben. Der Befehl wird abgebrochen und hat keinen Effekt, wenn das Ziel bereits als Datei oder Ordner existiert.

1: Überschreibe bestehende Dateien. Sollten Dateien oder Ordner im Ziel bestehen, die kein Gegenstück in der Quelle haben, so werden diese nicht gelöscht.

Dieser Parameter kann ein Ausdruck sein, selbst wenn dieser True oder False ist (da True und False international als 1 und 0 gewertet werden).

ErrorLevel

ErrorLevel wird auf 1 gesetzt, sollte ein Fehler aufgetreten sein, ansonsten 0.

Anmerkungen

Sollte die Ordnerstruktur im Ziel nicht existieren, so wird diese wenn möglich angelegt.

Da der Befehl Ordner mit Unterordner und Dateien rekursiv kopiert, ist ein Kopieren des Quellordners mit einem Ziel innerhalb des Quellordners nicht definiert. Um dies zu bewerkstelligen, kopieren Sie zuerst den Ordner außerhalb des Ordners und verwenden dann FileMoveDir um die Kopie in den gewünschten Zielordner zu verschieben.

FileCopyDir kopiert einen einzigen Ordner. Um alle Dateien und Unterordner eines Ordners zu kopieren, schauen Sie bitte in die Beispielsektion von FileCopy.

Siehe auch

FileMoveDir, FileCopy, FileMove, FileDelete, Datei-loops, FileSelectFolder, SplitPath

Beispiele

FileCopyDir, C:\Mein Ordner, C:\Kopie von Mein Ordner

; Beispiel #2: Ein funktionierendes Skript, das nach den zu kopierenden Ordner fragt.
FileSelectFolder, Quellordner, , 3, Wählen Sie einen Ordner zum kopieren
if Quellordner =
    return
; Ansonsten mache weiter
FileSelectFolder, Zielordner, , 3, Wählen Sie den Zielordner
if Zielordner =
    return
; Ansonsten mache weiter
MsgBox, 4, , Eine Kopie des Ordners "%Quellordner%" wurde in "%Zielordner%" angelegt.  Fortfahren?
IfMsgBox, No
    return
SplitPath, Quellordner, Quellordnernamen  ; Extrahiere nur den Ordnernamen des vollen Quellpfades
FileCopyDir, %Quellordner%, %Zielordner%\%Quellordnernamen%
if ErrorLevel
    MsgBox Der Ordner konnte nicht kopiert werden. Möglicherweise existiert bereits dieser Ordner in "%Zielordner%".
return